///////////////////////////////////////////////////////////////////////////
//  Copyright (C) Wizardry and Steamworks 2011 - License: GNU GPLv3      //
//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,  //
//  rights of fair usage, the disclaimer and warranty conditions.        //
///////////////////////////////////////////////////////////////////////////
//               _                           _  
//     |_|  _. _|_ _|_ o  _  |  _|  _   |_| | | | \ 
//     | | (_|  |_  |  | (/_ | (_| _>   | | |_| |_/ 
//                                              
///////////////////////////////////////////////////////////////////////////
//                            CONFIGURATION                              //
///////////////////////////////////////////////////////////////////////////

// Set this to the maximum possible velocity a player 
// can induce into the volleyball.

integer MAX_VELOCITY = 50;

///////////////////////////////////////////////////////////////////////////
//                          END CONFIGURATION                            //
///////////////////////////////////////////////////////////////////////////

///////////////////////////////////////////////////////////////////////////
//                              INTERNALS                                //
///////////////////////////////////////////////////////////////////////////

float Ox;
float Oy;
float Oz;
float Sx;
float Sy;

integer velocity=2;
integer comHandle;
integer comChannel;

init() {
    llSetColor(<0,0,0>, ALL_SIDES);
    list alpha = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z"];
    integer itra;
    integer ahash;
    for(itra=0, ahash=0; itra<llStringLength(llGetScriptName()); ++itra) {
        ahash += llListFindList(alpha, (list)llToLower(llGetSubString(llGetScriptName(), itra, itra)));
    }
    comChannel = ahash + ((integer)("0x"+llGetSubString((string)llGetCreator(),-8,-1)) & 0x3FFFFFFF) ^ 0xBFFFFFFF;
    comHandle = llListen(comChannel, "", "", "");
    llSetTimerEvent(2+llGetRegionTimeDilation());
}

default
{
    on_rez(integer start_param) {
        init();
    }
    
    attach(key id) {
        init();
    }
    
    state_entry() {
        init();
    }
    
    timer() {
        llRegionSay(comChannel, "@rc");
    }
    
    listen(integer channel, string name, key id, string message) {
        list calibData = llParseString2List(message, ["="], []);
        if(llList2String(calibData,0)!="@ac") return;
        llSetTimerEvent(0);
        llListenRemove(comHandle);
        calibData = llCSV2List(llList2String(calibData,1));
        Ox = llList2Float(calibData, 0);
        Oy = llList2Float(calibData, 1);
        Oz = llList2Float(calibData, 2);
        Sx = llList2Float(calibData, 3);
        Sy = llList2Float(calibData, 4);
        list alpha = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z"];
        integer itra;
        integer mhash;
        string mfield = llList2String(llParseString2List(llGetScriptName(), [" - "], []),1);
        for(itra=0, mhash=0; itra<llStringLength(mfield); ++itra) {
            mhash += llListFindList(alpha, (list)llToLower(llGetSubString(mfield, itra, itra)));
        }
        comChannel = mhash + ((integer)("0x"+llGetSubString((string)llGetCreator(),-8,-1)) & 0x3FFFFFFF) ^ 0xBFFFFFFF;
        llSetColor(<0,0,1>, ALL_SIDES);
    }
    
    touch(integer num_detected)
    {
        if(velocity<MAX_VELOCITY) ++velocity;
        llMessageLinked(LINK_THIS, 1, "", "");       
    }
    
    touch_end(integer num_detected) {
        vector tp = llDetectedTouchST(0);
        float dx = (Ox+(tp.x-.5)*200/100*Sx/2);
        float dy = (Oy+(tp.y-.5)*200/100*Sy/2);
        llRegionSay(comChannel+1, "@la=" + (string)((tp.y-.5)*-2)+ "," + (string)((tp.x-.5)*2));
        llWhisper(comChannel, (string)dx + "," + (string)dy + "," + (string)Oz + "," + (string)velocity);
        velocity=0;
    }

}